Posts made by PascalS

@felmue Finally I got the solution using separate Wires and PlattformIO to manage my libraries :)

With the following ini file (PlattformIO config file)

[env:miniscale]
platform = espressif32@6.1.0
board = m5stick-c
framework = arduino
lib_ldf_mode = deep
monitor_speed = 115200
build_flags = 
	-DCORE_DEBUG_LEVEL=0
	-Wl,--allow-multiple-definition
lib_deps = 
	https://github.com/m5stack/M5StickCPlus2.git
	m5stack/M5Unit-ENV@^1.0.1

Not knowing why, but I need the "-Wl" to run at all and the "--allow-multiple-definition" flag for the hat to work in conjunction with sensors mounted to the groove port.
It worked, however, I need to change the I2C begin call from "Wire0" (just called Wire) to the secondary I2C channel Wire1

Before:

while (!qmp.begin(&Wire, QMP6988_SLAVE_ADDRESS_L, 0, 26, 400000U)) {
     Serial.println("QMP6988 not found");
 }

After:

while (!qmp.begin(&Wire1, QMP6988_SLAVE_ADDRESS_L, 0, 26, 400000U)) {
     Serial.println("QMP6988 not found");
 }

Maybe this helps someone in the future :)

@felmue You were right, in UIFlow 2 it worked perfectly fine. However, I need them to work in Arduino, so that it fits with our current framework.

Do you know were the difference between UIFlow 2 and Arduino is?

@felmue Unfortunately, also a newly bought M5Stick and a newly bought ENV hat didn´t change anything.

Could it be that the hat port uses another Wire?

For the sake of completeness, I found my error.

I assumed, due to the writing on the back, that the ports must be 21/22. However, the SDA/SCL ports for the groove port are 32/33.

while (!scales.begin(&Wire, 32, 33, DEVICE_DEFAULT_ADDR))
  {
    Serial.println("scales connect error");
    M5.Lcd.print("scales connect error");
    delay(1000);
  }

Changing the ports in the scales.begin fixed the error.

Greetings Pascal

Hello to all,

The M5StickCPlus2 has a weird behaviour in regards to the I2c bus.

Before my M5Stick arrived, I tested the M5Stack Mini Scale with my Esp32 (Doit Devkit 1) successfully with the following code.

#include <Arduino.h>
#include <M5Unified.h>
#include "UNIT_SCALES.h"

#include <WiFi.h>
#include <PubSubClient.h>

#include <InfluxDbClient.h>
#include <InfluxDbCloud.h>

#define millis_between_readings 500

// WiFi
const char* ssid = ".....";
const char* password = "....";

#if defined(ESP32)
  #include <WiFiMulti.h>
  WiFiMulti wifiMulti;
  #define DEVICE "ESP32"
#elif defined(ESP8266)
  #include <ESP8266WiFiMulti.h>
  ESP8266WiFiMulti wifiMulti;
  #define DEVICE "ESP8266"
#endif


#define INFLUXDB_URL "....."
#define INFLUXDB_TOKEN "....."
#define INFLUXDB_ORG "...."
#define INFLUXDB_BUCKET "...."
  
// Time zone info
#define TZ_INFO "UTC2"
  
// Declare InfluxDB client instance with preconfigured InfluxCloud certificate
InfluxDBClient client(INFLUXDB_URL, INFLUXDB_ORG, INFLUXDB_BUCKET, INFLUXDB_TOKEN, InfluxDbCloud2CACert);
  
// Declare Data point
Point sensorP("ESP32_1");

UNIT_SCALES scales;


void setup()
{

  M5.begin();
  
  // Setup wifi
  Serial.print("Connecting to WiFi: [");
  Serial.print(ssid);
  Serial.print("] password: [");
  Serial.print(password);
  Serial.print("]");
  Serial.println();
  Serial.print("Connecting to wifi");

  WiFi.mode(WIFI_STA);
  wifiMulti.addAP(ssid, password);

  WiFi.disconnect();
  delay(1);
  while (wifiMulti.run() != WL_CONNECTED) {
    Serial.println(WiFi.status());
    Serial.print(" ");
    delay(1000);
  }

  Serial.println("Connected to the Wi-Fi network");
    // Accurate time is necessary for certificate validation and writing in batches
  // We use the NTP servers in your area as provided by: https://www.pool.ntp.org/zone/
  // Syncing progress and the time will be printed to Serial.
  timeSync(TZ_INFO, "pool.ntp.org", "time.nis.gov");

    // Check server connection
  if (client.validateConnection()) {
    Serial.print("Connected to InfluxDB: ");
    Serial.println(client.getServerUrl());
  } else {
    Serial.print("InfluxDB connection failed: ");
    Serial.println(client.getLastErrorMessage());
  }

  sensorP.addTag("device", DEVICE);
  sensorP.addTag("sensorType", "HT711");

  
  while (!scales.begin(&Wire, 21, 22, DEVICE_DEFAULT_ADDR))
  {
    Serial.println("scales connect error");
    M5.Lcd.print("scales connect error");
    delay(1000);
  }
}

char *toCharArray(String str)
{
  return &str[0];
}

void loop()
{
  // Clear fields for reusing the point. Tags will remain the same as set above.
  sensorP.clearFields();


  
  // Delay between measurements.
  sensorP.addField("weight", scales.getWeight());
  sensorP.addField("gap",  scales.getGapValue());
  sensorP.addField("adc",  scales.getRawADC());
  // Write point
  if (!client.writePoint(sensorP)) {
    Serial.print("InfluxDB write failed: ");
    Serial.println(client.getLastErrorMessage());
  }
  
  Serial.println("Pausing till next reading");
  delay(millis_between_readings);
}

Here is a picture of the wiring I used to bridge the gap between the M5 connector and the Devkit 1. (Green: VIN, Gray: GND, Purple: D21, White D22).

Anyone any idea what these two boards work differently?

Greetings Pascal

@felmue Thanks for your help :)

Propably it is a hardware failure, I do not get any i2c signals back.

Wil return it and run it with new hardware. I update the thread when I heard back from the seller.

Thanks for your help!

Greetings Pascal

@felmue

The port scan went as expect, only internals are found.

I2C Scan - internal
................................................................................0x51 ......................0x68 ......................
I2C Scan - Groove Port
..............................................................................................................................
I2C Scan - Hat Port
..............................................................................................................................

Does that mean a hardware error?

Greetings Pascal

@felmue Thanks for the link.

Strangely, they are now not showing up (not found is now in the log). That wasnt before.

@felmue From your posts, I get the feeling that you have a lot of knowledge. :)

As a last ressort, I tried to find a I2C scanner sketch and ended up with the following code.

/*********
  Rui Santos
  Complete project details at https://randomnerdtutorials.com  
*********/

#include <Wire.h>
 
void setup() {
  Wire.begin();
  Serial.begin(115200);
  Serial.println("\nI2C Scanner");
}
 
void loop() {
  byte error, address;
  int nDevices;
  Serial.println("Scanning...");
  nDevices = 0;
  for(address = 1; address < 127; address++ ) {
    Wire.beginTransmission(address);
    error = Wire.endTransmission();
    if (error == 0) {
      Serial.print("I2C device found at address 0x");
      if (address<16) {
        Serial.print("0");
      }
      Serial.println(address,HEX);
      nDevices++;
    }
    else if (error==4) {
      Serial.print("Unknow error at address 0x");
      if (address<16) {
        Serial.print("0");
      }
      Serial.println(address,HEX);
    }    
  }
  if (nDevices == 0) {
    Serial.println("No I2C devices found\n");
  }
  else {
    Serial.println("done\n");
  }
  delay(5000);          
}

I was not sure, but in all the sketches they used sda=0 and scl=26.

If I scan those, I cant get any devices found. However, if I scan the standard sda/scl = 21/22, then I find two devices (propably build into the Stick itself).

Is this a sign for an hardware failure?

Greetings Pascal

@felmue Thanks for your test.

Unfortunately I cant get either of them to connect.

Is their a difference between Hat and Unit? Which library versions did you use?

Hi everyone,

I am currently struggeling with getting my newly purchesd ENV 3 Hat and StickC Plus 2 to work.

Current Error: "ENV Hat 3 and StickC Plus 2 [Wire.513] requestFrom(): i2cRead returned Error 263"

My code looks like this:

It is a combination of these two example (Example1, Example2)

#include "M5StickCPlus2.h"
#include "M5UnitENV.h"

SHT3X sht3x;
QMP6988 qmp;

void draw_function(LovyanGFX* gfx) {
    int x      = rand() % gfx->width();
    int y      = rand() % gfx->height();
    int r      = (gfx->width() >> 4) + 2;
    uint16_t c = rand();
    gfx->fillRect(x - r, y - r, r * 2, r * 2, c);
}

void setup() {
    auto cfg = M5.config();
    StickCP2.begin(cfg);
    int textsize = StickCP2.Display.height() / 60;
    if (textsize == 0) {
        textsize = 1;
    }
    StickCP2.Display.setTextSize(textsize);
    
    if (!qmp.begin(&Wire, QMP6988_SLAVE_ADDRESS_L, 0, 26, 400000U)) {
        Serial.println("Couldn't find QMP6988");
        while (1) delay(1);
    }

    if (!sht3x.begin(&Wire, SHT3X_I2C_ADDR, 0, 26, 400000U)) {
        Serial.println("Couldn't find SHT3X");
        while (1) delay(1);
    }
}

void loop() {
    int x      = rand() % StickCP2.Display.width();
    int y      = rand() % StickCP2.Display.height();
    int r      = (StickCP2.Display.width() >> 4) + 2;
    uint16_t c = rand();
    StickCP2.Display.fillCircle(x, y, r, c);
    draw_function(&StickCP2.Display);

      if (sht3x.update()) {
        Serial.println("-----SHT3X-----");
        Serial.print("Temperature: ");
        Serial.print(sht3x.cTemp);
        Serial.println(" degrees C");
        Serial.print("Humidity: ");
        Serial.print(sht3x.humidity);
        Serial.println("% rH");
        Serial.println("-------------\r\n");
    }

    if (qmp.update()) {
        Serial.println("-----QMP6988-----");
        Serial.print(F("Temperature: "));
        Serial.print(qmp.cTemp);
        Serial.println(" *C");
        Serial.print(F("Pressure: "));
        Serial.print(qmp.pressure);
        Serial.println(" Pa");
        Serial.print(F("Approx altitude: "));
        Serial.print(qmp.altitude);
        Serial.println(" m");
        Serial.println("-------------\r\n");
    }
    delay(1000);
}

Produces the following output:

*[377696][E][Wire.cpp:513] requestFrom(): i2cRead returned Error 263
[377724][E][Wire.cpp:513] requestFrom(): i2cRead returned Error 263
-----QMP6988-----
Temperature: 0.00 C
Pressure: 0.00 Pa
Approx altitude: inf m
-------------

I am happy for any help to get these two to work :)

Greetings Pascal