Kind of an old thread but I wanted to respond since it may help others who are trying to get this module to work, not much out there on the Arduino coding side.

I believe the issue might be the pin assignment for step and dir, it's actually printed on the PCB. For the Core2 X, Y, Z step = 13, 27, 2 and dir = 14, 19, 0 respectively. So I'm not sure why STEP_PIN is set to 15, maybe this is the legacy Core?

I used the same referenced Stepmotor code (https://github.com/m5stack/M5Module-Stepmotor) and did get it working eventually. Here is some very basic example code that may help:

#include <M5Unified.h>
#include "Module_Stepmotor.h"

// change to CORE2 if using Core2
#define CORE_S3

#ifdef CORE_S3
    static const int X_STEP_PIN = 18;
    static const int X_DIR_PIN = 17;
    static const int Y_STEP_PIN = 6;
    static const int Y_DIR_PIN = 7;
    static const int Z_STEP_PIN = 13;
    static const int Z_DIR_PIN = 0;
    
    static const int SDA_PIN = 12;
    static const int SCL_PIN = 11;
#elif defined CORE2
    static const int X_STEP_PIN = 13;
    static const int X_DIR_PIN = 14;
    static const int Y_STEP_PIN = 27;
    static const int Y_DIR_PIN = 19;
    static const int Z_STEP_PIN = 2; // Not sure about this one
    static const int Z_DIR_PIN = 0;

    static const int SDA_PIN = 21;
    static const int SCL_PIN = 22;
#endif

static Module_Stepmotor driver;

void setup() {
    Wire.begin(SDA_PIN, SCL_PIN, 400000UL);

    driver.init(Wire, 0x27);
    driver.resetMotor(0, 0);
    driver.resetMotor(1, 0);
    driver.resetMotor(2, 0);
    driver.enableMotor(1);

    // PWM, sets the speed of the stepper motor, adjust accordingly
    ledcSetup(0, 500, 8);

    // XYZ step
    ledcAttachPin(X_STEP_PIN, 0);
    ledcAttachPin(Y_STEP_PIN, 0);
    ledcAttachPin(Z_STEP_PIN, 0);

    ledcWrite(0, 127);

    // XYZ dir
    pinMode(X_DIR_PIN, OUTPUT);
    digitalWrite(X_DIR_PIN, 1);
    pinMode(Y_DIR_PIN, OUTPUT);
    digitalWrite(Y_DIR_PIN, 1);
    pinMode(Z_DIR_PIN, OUTPUT);
    digitalWrite(Z_DIR_PIN, 1);
}

void loop() {
    digitalWrite(X_DIR_PIN, 0);
    delay(2000);
    digitalWrite(X_DIR_PIN, 1);
    delay(2000);
}

Not sure if you're referring to the hat or port ENV III but the get method of SHT3X didn't have the correct begin for the ENV III hat, so I brought the method into main and manually set up Wire.begin(25, 26) as seen below:

#include "M5CoreInk.h"
#include "M5_ENV.h"

//SHT3X sht30;
QMP6988 qmp6988;

float tmp      = 0.0;
float hum      = 0.0;
float pressure = 0.0;

Ink_Sprite InkPageSprite(&M5.M5Ink);

void setup() {

  M5.begin();
  Wire.begin(25, 26);

  qmp6988.init();

  if ( !M5.M5Ink.isInit()) {
    Serial.printf("Ink Init faild");
    while (1) delay(100);
  }
  M5.M5Ink.clear();   //Clear screen.
  delay(1000);
  if ( InkPageSprite.creatSprite(0, 0, 200, 200, true) != 0) {
    Serial.printf("Ink Sprite creat faild");
  }
}


byte getVal()
{
  unsigned int data[6];

  // Start I2C Transmission
  Wire.beginTransmission(0x44);

  // Send measurement command
  Wire.write(0x2C);
  Wire.write(0x06);

  // Stop I2C transmission
  if (Wire.endTransmission() != 0)
    return 1;

  delay(200);

  // Request 6 bytes of data
  Wire.requestFrom(0x44, 6);

  // Read 6 bytes of data
  // cTemp msb, cTemp lsb, cTemp crc, humidity msb, humidity lsb, humidity crc
  for (int i = 0; i < 6; i++) {
    data[i] = Wire.read();
  };

  delay(50);

  if (Wire.available() != 0)
    return 2;

  // Convert the data
  float cTemp = ((((data[0] * 256.0) + data[1]) * 175) / 65535.0) - 45;
  tmp = (cTemp * 1.8) + 32;
  hum = ((((data[3] * 256.0) + data[4]) * 100) / 65535.0);

  return 0;
}

void loop() {
  pressure = qmp6988.calcPressure();
  if (getVal() == 0) {
    char buf[20];

    snprintf(buf, 20, "Temp: %2.1f F", tmp);
    InkPageSprite.drawString(40, 20, buf);

    snprintf(buf, 20, "Humi: %2.0f%%", hum);
    InkPageSprite.drawString(40, 40, buf);

    snprintf(buf, 20, "Pres: %2.0f Pa", pressure);
    InkPageSprite.drawString(40, 60, buf);
  }

  InkPageSprite.pushSprite(); //Push the sprite to the screen.
  delay(1000);
}

It's pretty basic in functionality, but it works for the most part. And again, this is for the ENV III hat.